File Manager

X7ROOT File Manager

Current Path: /opt/golang/1.22.0/src/math

📁 ..
📄 abs.go(366 B)
📄 acos_s390x.s(3.73 KB)
📄 acosh.go(1.71 KB)
📄 acosh_s390x.s(4.32 KB)
📄 all_test.go(86.77 KB)
📄 arith_s390x.go(3.73 KB)
📄 arith_s390x_test.go(10.78 KB)
📄 asin.go(1.09 KB)
📄 asin_s390x.s(4.16 KB)
📄 asinh.go(1.92 KB)
📄 asinh_s390x.s(5.74 KB)
📄 atan.go(3.03 KB)
📄 atan2.go(1.52 KB)
📄 atan2_s390x.s(6.93 KB)
📄 atan_s390x.s(3.69 KB)
📄 atanh.go(1.99 KB)
📄 atanh_s390x.s(5.06 KB)
📁 big
📁 bits
📄 bits.go(1.87 KB)
📄 cbrt.go(2.31 KB)
📄 cbrt_s390x.s(4.89 KB)
📁 cmplx
📄 const.go(2.76 KB)
📄 const_test.go(1.29 KB)
📄 copysign.go(396 B)
📄 cosh_s390x.s(5.59 KB)
📄 dim.go(1.87 KB)
📄 dim_amd64.s(1.92 KB)
📄 dim_arm64.s(963 B)
📄 dim_asm.go(344 B)
📄 dim_noasm.go(410 B)
📄 dim_riscv64.s(1.16 KB)
📄 dim_s390x.s(1.97 KB)
📄 erf.go(11.51 KB)
📄 erf_s390x.s(8.5 KB)
📄 erfc_s390x.s(14.4 KB)
📄 erfinv.go(3.37 KB)
📄 example_test.go(3.75 KB)
📄 exp.go(5.38 KB)
📄 exp2_asm.go(252 B)
📄 exp2_noasm.go(284 B)
📄 exp_amd64.go(261 B)
📄 exp_amd64.s(4.24 KB)
📄 exp_arm64.s(5.36 KB)
📄 exp_asm.go(268 B)
📄 exp_noasm.go(302 B)
📄 exp_s390x.s(4.65 KB)
📄 expm1.go(7.91 KB)
📄 expm1_s390x.s(5.29 KB)
📄 export_s390x_test.go(732 B)
📄 export_test.go(357 B)
📄 floor.go(3.29 KB)
📄 floor_386.s(1.47 KB)
📄 floor_amd64.s(2 KB)
📄 floor_arm64.s(573 B)
📄 floor_asm.go(431 B)
📄 floor_noasm.go(531 B)
📄 floor_ppc64x.s(499 B)
📄 floor_s390x.s(579 B)
📄 floor_wasm.s(459 B)
📄 fma.go(4.61 KB)
📄 frexp.go(929 B)
📄 gamma.go(5.53 KB)
📄 huge_test.go(2.91 KB)
📄 hypot.go(850 B)
📄 hypot_386.s(1.81 KB)
📄 hypot_amd64.s(1.05 KB)
📄 hypot_asm.go(264 B)
📄 hypot_noasm.go(297 B)
📄 j0.go(13.6 KB)
📄 j1.go(13.3 KB)
📄 jn.go(7.18 KB)
📄 ldexp.go(1.05 KB)
📄 lgamma.go(11.03 KB)
📄 log.go(3.86 KB)
📄 log10.go(873 B)
📄 log10_s390x.s(4.73 KB)
📄 log1p.go(6.34 KB)
📄 log1p_s390x.s(5.15 KB)
📄 log_amd64.s(3.66 KB)
📄 log_asm.go(259 B)
📄 log_s390x.s(4.31 KB)
📄 log_stub.go(292 B)
📄 logb.go(1021 B)
📄 mod.go(903 B)
📄 modf.go(913 B)
📄 modf_arm64.s(447 B)
📄 modf_asm.go(292 B)
📄 modf_noasm.go(326 B)
📄 modf_ppc64x.s(416 B)
📄 nextafter.go(1.21 KB)
📄 pow.go(3.65 KB)
📄 pow10.go(1.24 KB)
📄 pow_s390x.s(16.27 KB)
📁 rand
📄 remainder.go(2.04 KB)
📄 signbit.go(302 B)
📄 sin.go(6.35 KB)
📄 sin_s390x.s(8.57 KB)
📄 sincos.go(1.76 KB)
📄 sinh.go(1.69 KB)
📄 sinh_s390x.s(5.98 KB)
📄 sqrt.go(4.75 KB)
📄 stubs.go(2.57 KB)
📄 stubs_s390x.s(12.38 KB)
📄 tan.go(3.68 KB)
📄 tan_s390x.s(2.72 KB)
📄 tanh.go(2.66 KB)
📄 tanh_s390x.s(4.57 KB)
📄 trig_reduce.go(3.34 KB)
📄 unsafe.go(1.27 KB)

Editing: log_amd64.s

// Copyright 2010 The Go Authors. All rights reserved.
// Use of this source code is governed by a BSD-style
// license that can be found in the LICENSE file.

#include "textflag.h"

#define HSqrt2 7.07106781186547524401e-01 // sqrt(2)/2
#define Ln2Hi  6.93147180369123816490e-01 // 0x3fe62e42fee00000
#define Ln2Lo  1.90821492927058770002e-10 // 0x3dea39ef35793c76
#define L1     6.666666666666735130e-01   // 0x3FE5555555555593
#define L2     3.999999999940941908e-01   // 0x3FD999999997FA04
#define L3     2.857142874366239149e-01   // 0x3FD2492494229359
#define L4     2.222219843214978396e-01   // 0x3FCC71C51D8E78AF
#define L5     1.818357216161805012e-01   // 0x3FC7466496CB03DE
#define L6     1.531383769920937332e-01   // 0x3FC39A09D078C69F
#define L7     1.479819860511658591e-01   // 0x3FC2F112DF3E5244
#define NaN    0x7FF8000000000001
#define NegInf 0xFFF0000000000000
#define PosInf 0x7FF0000000000000

// func Log(x float64) float64
TEXT ·archLog(SB),NOSPLIT,$0
	// test bits for special cases
	MOVQ    x+0(FP), BX
	MOVQ    $~(1<<63), AX // sign bit mask
	ANDQ    BX, AX
	JEQ     isZero
	MOVQ    $0, AX
	CMPQ    AX, BX
	JGT     isNegative
	MOVQ    $PosInf, AX
	CMPQ    AX, BX
	JLE     isInfOrNaN
	// f1, ki := math.Frexp(x); k := float64(ki)
	MOVQ    BX, X0
	MOVQ    $0x000FFFFFFFFFFFFF, AX
	MOVQ    AX, X2
	ANDPD   X0, X2
	MOVSD   $0.5, X0 // 0x3FE0000000000000
	ORPD    X0, X2 // X2= f1
	SHRQ    $52, BX
	ANDL    $0x7FF, BX
	SUBL    $0x3FE, BX
	XORPS   X1, X1 // break dependency for CVTSL2SD
	CVTSL2SD BX, X1 // x1= k, x2= f1
	// if f1 < math.Sqrt2/2 { k -= 1; f1 *= 2 }
	MOVSD   $HSqrt2, X0 // x0= 0.7071, x1= k, x2= f1
	CMPSD   X2, X0, 5 // cmpnlt; x0= 0 or ^0, x1= k, x2 = f1
	MOVSD   $1.0, X3 // x0= 0 or ^0, x1= k, x2 = f1, x3= 1
	ANDPD   X0, X3 // x0= 0 or ^0, x1= k, x2 = f1, x3= 0 or 1
	SUBSD   X3, X1 // x0= 0 or ^0, x1= k, x2 = f1, x3= 0 or 1
	MOVSD   $1.0, X0 // x0= 1, x1= k, x2= f1, x3= 0 or 1
	ADDSD   X0, X3 // x0= 1, x1= k, x2= f1, x3= 1 or 2
	MULSD   X3, X2 // x0= 1, x1= k, x2= f1
	// f := f1 - 1
	SUBSD   X0, X2 // x1= k, x2= f
	// s := f / (2 + f)
	MOVSD   $2.0, X0
	ADDSD   X2, X0
	MOVAPD  X2, X3
	DIVSD   X0, X3 // x1=k, x2= f, x3= s
	// s2 := s * s
	MOVAPD  X3, X4 // x1= k, x2= f, x3= s
	MULSD   X4, X4 // x1= k, x2= f, x3= s, x4= s2
	// s4 := s2 * s2
	MOVAPD  X4, X5 // x1= k, x2= f, x3= s, x4= s2
	MULSD   X5, X5 // x1= k, x2= f, x3= s, x4= s2, x5= s4
	// t1 := s2 * (L1 + s4*(L3+s4*(L5+s4*L7)))
	MOVSD   $L7, X6
	MULSD   X5, X6
	ADDSD   $L5, X6
	MULSD   X5, X6
	ADDSD   $L3, X6
	MULSD   X5, X6
	ADDSD   $L1, X6
	MULSD   X6, X4 // x1= k, x2= f, x3= s, x4= t1, x5= s4
	// t2 := s4 * (L2 + s4*(L4+s4*L6))
	MOVSD   $L6, X6
	MULSD   X5, X6
	ADDSD   $L4, X6
	MULSD   X5, X6
	ADDSD   $L2, X6
	MULSD   X6, X5 // x1= k, x2= f, x3= s, x4= t1, x5= t2
	// R := t1 + t2
	ADDSD   X5, X4 // x1= k, x2= f, x3= s, x4= R
	// hfsq := 0.5 * f * f
	MOVSD   $0.5, X0
	MULSD   X2, X0
	MULSD   X2, X0 // x0= hfsq, x1= k, x2= f, x3= s, x4= R
	// return k*Ln2Hi - ((hfsq - (s*(hfsq+R) + k*Ln2Lo)) - f)
	ADDSD   X0, X4 // x0= hfsq, x1= k, x2= f, x3= s, x4= hfsq+R
	MULSD   X4, X3 // x0= hfsq, x1= k, x2= f, x3= s*(hfsq+R)
	MOVSD   $Ln2Lo, X4
	MULSD   X1, X4 // x4= k*Ln2Lo
	ADDSD   X4, X3 // x0= hfsq, x1= k, x2= f, x3= s*(hfsq+R)+k*Ln2Lo
	SUBSD   X3, X0 // x0= hfsq-(s*(hfsq+R)+k*Ln2Lo), x1= k, x2= f
	SUBSD   X2, X0 // x0= (hfsq-(s*(hfsq+R)+k*Ln2Lo))-f, x1= k
	MULSD   $Ln2Hi, X1 // x0= (hfsq-(s*(hfsq+R)+k*Ln2Lo))-f, x1= k*Ln2Hi
	SUBSD   X0, X1 // x1= k*Ln2Hi-((hfsq-(s*(hfsq+R)+k*Ln2Lo))-f)
	MOVSD   X1, ret+8(FP)
	RET
isInfOrNaN:
	MOVQ    BX, ret+8(FP) // +Inf or NaN, return x
	RET
isNegative:
	MOVQ    $NaN, AX
	MOVQ    AX, ret+8(FP) // return NaN
	RET
isZero:
	MOVQ    $NegInf, AX
	MOVQ    AX, ret+8(FP) // return -Inf
	RET

X7ROOT File Manager

Editing: log_amd64.s

Upload File

Create Folder