File Manager

X7ROOT File Manager

Current Path: /opt/golang/1.19.4/src/math/big

opt / golang / 1.19.4 / src / math / big /

📁 ..
📄 accuracy_string.go(414 B)
📄 alias_test.go(8.81 KB)
📄 arith.go(8.28 KB)
📄 arith_386.s(4.07 KB)
📄 arith_amd64.go(306 B)
📄 arith_amd64.s(9.09 KB)
📄 arith_arm.s(4.03 KB)
📄 arith_arm64.s(11.88 KB)
📄 arith_decl.go(594 B)
📄 arith_decl_pure.go(1.04 KB)
📄 arith_decl_s390x.go(531 B)
📄 arith_loong64.s(745 B)
📄 arith_mips64x.s(817 B)
📄 arith_mipsx.s(809 B)
📄 arith_ppc64x.s(16.36 KB)
📄 arith_riscv64.s(786 B)
📄 arith_s390x.s(20.32 KB)
📄 arith_s390x_test.go(812 B)
📄 arith_test.go(19.88 KB)
📄 arith_wasm.s(641 B)
📄 bits_test.go(5.07 KB)
📄 calibrate_test.go(4.63 KB)
📄 decimal.go(6.63 KB)
📄 decimal_test.go(3.33 KB)
📄 doc.go(3.79 KB)
📄 example_rat_test.go(1.68 KB)
📄 example_test.go(4.05 KB)
📄 float.go(44.28 KB)
📄 float_test.go(51.94 KB)
📄 floatconv.go(8.34 KB)
📄 floatconv_test.go(24.27 KB)
📄 floatexample_test.go(3.63 KB)
📄 floatmarsh.go(3.53 KB)
📄 floatmarsh_test.go(3.92 KB)
📄 ftoa.go(13.55 KB)
📄 gcd_test.go(2.16 KB)
📄 hilbert_test.go(2.88 KB)
📄 int.go(30.26 KB)
📄 int_test.go(53.14 KB)
📄 intconv.go(6.69 KB)
📄 intconv_test.go(10.01 KB)
📄 intmarsh.go(2.14 KB)
📄 intmarsh_test.go(3.07 KB)
📄 link_test.go(1.4 KB)
📄 nat.go(26.73 KB)
📄 nat_test.go(23.56 KB)
📄 natconv.go(14.55 KB)
📄 natconv_test.go(16.85 KB)
📄 natdiv.go(34.15 KB)
📄 prime.go(10.34 KB)
📄 prime_test.go(7.1 KB)
📄 rat.go(13.47 KB)
📄 rat_test.go(18.89 KB)
📄 ratconv.go(9.78 KB)
📄 ratconv_test.go(15.75 KB)
📄 ratmarsh.go(2.1 KB)
📄 ratmarsh_test.go(3.3 KB)
📄 roundingmode_string.go(501 B)
📄 sqrt.go(2.79 KB)
📄 sqrt_test.go(4.81 KB)

Editing: arith_386.s

// Copyright 2009 The Go Authors. All rights reserved.
// Use of this source code is governed by a BSD-style
// license that can be found in the LICENSE file.

//go:build !math_big_pure_go
// +build !math_big_pure_go

#include "textflag.h"

// This file provides fast assembly versions for the elementary
// arithmetic operations on vectors implemented in arith.go.

// func addVV(z, x, y []Word) (c Word)
TEXT ·addVV(SB),NOSPLIT,$0
	MOVL z+0(FP), DI
	MOVL x+12(FP), SI
	MOVL y+24(FP), CX
	MOVL z_len+4(FP), BP
	MOVL $0, BX		// i = 0
	MOVL $0, DX		// c = 0
	JMP E1

L1:	MOVL (SI)(BX*4), AX
	ADDL DX, DX		// restore CF
	ADCL (CX)(BX*4), AX
	SBBL DX, DX		// save CF
	MOVL AX, (DI)(BX*4)
	ADDL $1, BX		// i++

E1:	CMPL BX, BP		// i < n
	JL L1

NEGL DX
	MOVL DX, c+36(FP)
	RET

// func subVV(z, x, y []Word) (c Word)
// (same as addVV except for SBBL instead of ADCL and label names)
TEXT ·subVV(SB),NOSPLIT,$0
	MOVL z+0(FP), DI
	MOVL x+12(FP), SI
	MOVL y+24(FP), CX
	MOVL z_len+4(FP), BP
	MOVL $0, BX		// i = 0
	MOVL $0, DX		// c = 0
	JMP E2

L2:	MOVL (SI)(BX*4), AX
	ADDL DX, DX		// restore CF
	SBBL (CX)(BX*4), AX
	SBBL DX, DX		// save CF
	MOVL AX, (DI)(BX*4)
	ADDL $1, BX		// i++

E2:	CMPL BX, BP		// i < n
	JL L2

NEGL DX
	MOVL DX, c+36(FP)
	RET

// func addVW(z, x []Word, y Word) (c Word)
TEXT ·addVW(SB),NOSPLIT,$0
	MOVL z+0(FP), DI
	MOVL x+12(FP), SI
	MOVL y+24(FP), AX	// c = y
	MOVL z_len+4(FP), BP
	MOVL $0, BX		// i = 0
	JMP E3

L3:	ADDL (SI)(BX*4), AX
	MOVL AX, (DI)(BX*4)
	SBBL AX, AX		// save CF
	NEGL AX
	ADDL $1, BX		// i++

E3:	CMPL BX, BP		// i < n
	JL L3

MOVL AX, c+28(FP)
	RET

// func subVW(z, x []Word, y Word) (c Word)
TEXT ·subVW(SB),NOSPLIT,$0
	MOVL z+0(FP), DI
	MOVL x+12(FP), SI
	MOVL y+24(FP), AX	// c = y
	MOVL z_len+4(FP), BP
	MOVL $0, BX		// i = 0
	JMP E4

L4:	MOVL (SI)(BX*4), DX
	SUBL AX, DX
	MOVL DX, (DI)(BX*4)
	SBBL AX, AX		// save CF
	NEGL AX
	ADDL $1, BX		// i++

E4:	CMPL BX, BP		// i < n
	JL L4

MOVL AX, c+28(FP)
	RET

// func shlVU(z, x []Word, s uint) (c Word)
TEXT ·shlVU(SB),NOSPLIT,$0
	MOVL z_len+4(FP), BX	// i = z
	SUBL $1, BX		// i--
	JL X8b			// i < 0	(n <= 0)

// n > 0
	MOVL z+0(FP), DI
	MOVL x+12(FP), SI
	MOVL s+24(FP), CX
	MOVL (SI)(BX*4), AX	// w1 = x[n-1]
	MOVL $0, DX
	SHLL CX, AX, DX		// w1>>ŝ
	MOVL DX, c+28(FP)

CMPL BX, $0
	JLE X8a			// i <= 0

// i > 0
L8:	MOVL AX, DX		// w = w1
	MOVL -4(SI)(BX*4), AX	// w1 = x[i-1]
	SHLL CX, AX, DX		// w<<s | w1>>ŝ
	MOVL DX, (DI)(BX*4)	// z[i] = w<<s | w1>>ŝ
	SUBL $1, BX		// i--
	JG L8			// i > 0

// i <= 0
X8a:	SHLL CX, AX		// w1<<s
	MOVL AX, (DI)		// z[0] = w1<<s
	RET

X8b:	MOVL $0, c+28(FP)
	RET

// func shrVU(z, x []Word, s uint) (c Word)
TEXT ·shrVU(SB),NOSPLIT,$0
	MOVL z_len+4(FP), BP
	SUBL $1, BP		// n--
	JL X9b			// n < 0	(n <= 0)

// n > 0
	MOVL z+0(FP), DI
	MOVL x+12(FP), SI
	MOVL s+24(FP), CX
	MOVL (SI), AX		// w1 = x[0]
	MOVL $0, DX
	SHRL CX, AX, DX		// w1<<ŝ
	MOVL DX, c+28(FP)

MOVL $0, BX		// i = 0
	JMP E9

// i < n-1
L9:	MOVL AX, DX		// w = w1
	MOVL 4(SI)(BX*4), AX	// w1 = x[i+1]
	SHRL CX, AX, DX		// w>>s | w1<<ŝ
	MOVL DX, (DI)(BX*4)	// z[i] = w>>s | w1<<ŝ
	ADDL $1, BX		// i++

E9:	CMPL BX, BP
	JL L9			// i < n-1

// i >= n-1
X9a:	SHRL CX, AX		// w1>>s
	MOVL AX, (DI)(BP*4)	// z[n-1] = w1>>s
	RET

X9b:	MOVL $0, c+28(FP)
	RET

// func mulAddVWW(z, x []Word, y, r Word) (c Word)
TEXT ·mulAddVWW(SB),NOSPLIT,$0
	MOVL z+0(FP), DI
	MOVL x+12(FP), SI
	MOVL y+24(FP), BP
	MOVL r+28(FP), CX	// c = r
	MOVL z_len+4(FP), BX
	LEAL (DI)(BX*4), DI
	LEAL (SI)(BX*4), SI
	NEGL BX			// i = -n
	JMP E5

L5:	MOVL (SI)(BX*4), AX
	MULL BP
	ADDL CX, AX
	ADCL $0, DX
	MOVL AX, (DI)(BX*4)
	MOVL DX, CX
	ADDL $1, BX		// i++

E5:	CMPL BX, $0		// i < 0
	JL L5

MOVL CX, c+32(FP)
	RET

// func addMulVVW(z, x []Word, y Word) (c Word)
TEXT ·addMulVVW(SB),NOSPLIT,$0
	MOVL z+0(FP), DI
	MOVL x+12(FP), SI
	MOVL y+24(FP), BP
	MOVL z_len+4(FP), BX
	LEAL (DI)(BX*4), DI
	LEAL (SI)(BX*4), SI
	NEGL BX			// i = -n
	MOVL $0, CX		// c = 0
	JMP E6

L6:	MOVL (SI)(BX*4), AX
	MULL BP
	ADDL CX, AX
	ADCL $0, DX
	ADDL AX, (DI)(BX*4)
	ADCL $0, DX
	MOVL DX, CX
	ADDL $1, BX		// i++

E6:	CMPL BX, $0		// i < 0
	JL L6

MOVL CX, c+28(FP)
	RET

X7ROOT File Manager

Editing: arith_386.s

Upload File

Create Folder